简单验证
使用 Visual Basic Scripting Edition，您可以完成通常要在服务器上进行的大量窗体处理工作，也可以完成不能在服务器上进行的工作。
这是一个简单的客户端验证的样例。HTML 代码的结果是一个文本框和一个按钮。如果使用 Microsoft? Internet Explorer 查看用以下代码制作的页面，您会看到一个旁边带有按钮的小文本框。
<HTML>
<HEAD><TITLE>简单验证</TITLE>
<SCRIPT LANGUAGE="VBScript">
<!--
Sub Submit_OnClick
Dim TheForm
Set TheForm = Document.ValidForm
If IsNumeric(TheForm.Text1.Value) Then
If TheForm.Text1.Value < 1 Or TheForm.Text1.Value > 10 Then
MsgBox "请输入一个 1 到 10 之间的数字。"
Else
MsgBox "谢谢。"
End If
Else
MsgBox "请输入一个数字。"
End If
End Sub
-->
</SCRIPT>
</HEAD>
<BODY>
<H3>简单验证</H3><HR>
<FORM NAME="ValidForm">
请输入一个 1 到 10 之间的数字：
<INPUT NAME="Text1" TYPE="TEXT" SIZE="2">
<INPUT NAME="Submit" TYPE="BUTTON" VALUE="提交">
</FORM>
</BODY>
</HTML>
这个文本框与 VBScript 页面的简单样例中示例的不同之处在于文本框的 Value 属性被用于检查输入值。要使用文本框的 Value 属性，代码必须引用文本框的名称。
每次引用文本框时都应写出全称，即 Document.ValidForm.Text1。但是，当多次引用窗体控件时，可以按照以下步骤操作：首先声明一个变量，然后使用 Set 语句将窗体 Document.ValidForm 赋给变量 TheForm，这样就能使用 TheForm.Text1 引用文本框。常规的赋值语句（例如 Dim）在这里无效，必须使用 Set 来保持对对象的引用。
使用数字
请注意以上示例直接检测输入值是否是一个数字：使用 IsNumeric 函数确定文本框中的字符串是否是一个数字。虽然 VBScript 能够自动转换字符串和数字，但检测用户输入值的数据子类型，并且在必要时使用转换函数始终是一个好的习惯。在用文本框的 Value 属性进行加法运算时，应将它显式地转换为数字，这是因为加号 (+) 操作符不但可进行加法操作，而且可进行字符串连接操作。例如，如果 Text1 中包含“1”，Text2 中包含“2”，您将会看到以下结果：
A = Text1.Value + Text2.Value ' A 为“12”
A = CDbl(Text1.Value) + Text2.Value ' A 为 3
验证后将数据传递回服务器
简单验证样例使用的是普通按钮控件。如果使用 Submit 控件，所有数据都会被立即传送到服务器，示例将不会看到数据来进行检查。避免使用 Submit 控件使您可以检查数据，但不能向服务器提交数据。如果要提交数据则需要再添加一行代码，如下所示：
<SCRIPT LANGUAGE="VBScript">
<!--
Sub Submit_OnClick
Dim TheForm
Set TheForm = Document.ValidForm
If IsNumeric(TheForm.Text1.Value) Then
If TheForm.Text1.Value < 1 Or TheForm.Text1.Value > 10 Then
MsgBox "请输入一个 1 到 10 之间的数字。"
Else
MsgBox "谢谢。"
TheForm.Submit ' 数据输入正确，传递到服务器。
End If
Else
MsgBox "请输入一个数字。"
End If
End Sub
-->
</SCRIPT>
在数据输入正确时，代码调用窗体对象的 Submit 方法，将数据传递到服务器。除非在数据被传递到服务器之前判断其正误，否则服务器将处理数据，而不论其正确与否。您可以在 Internet Explorer Script Object Model 页面上找到关于 Submit 方法和其他方法的全部信息。
到目前为止，您只看到了标准 HTML <FORM> 对象。Internet Explorer 还可以使您利用 ActiveX? 控件（以前称为 OLE 控件）和 Java? 对象的全部功能创建页面。
使用对象
无论使用的是 ActiveX? 控件（以前称为 OLE 控件）还是 Java? 对象，Microsoft Visual Basic Scripting Edition 和 Microsoft? Internet Explorer 都以相同的方式处理它们。如果您使用的是 Internet Explorer 并且 ActiveX 库中安装了这些控件，就会看到由以下代码制作的页面。
<OBJECT> 标记用来包含对象，<PARAM> 标记用来设置对象属性的初始值。使用 <PARAM> 标记类似于在 Visual Basic 中设置窗体控件的初始属性值。例如，以下代码使用 <OBJECT> 和 <PARAM> 标记将 ActiveX 标签控件添加到页面中：
<OBJECT
classid="clsid:99B42120-6EC7-11CF-A6C7-00AA00A47DD2"
id=lblActiveLbl
width=250
height=250
align=left
hspace=20
vspace=0
>
<PARAM NAME="Angle" VALUE="90">
<PARAM NAME="Alignment" VALUE="4">
<PARAM NAME="BackStyle" VALUE="0">
<PARAM NAME="Caption" VALUE="一个简单标签">
<PARAM NAME="FontName" VALUE="宋体">
<PARAM NAME="FontSize" VALUE="20">
<PARAM NAME="FontBold" VALUE="1">
<PARAM NAME="FrColor" VALUE="0">
</OBJECT>
象对任何窗体控件一样，可以获取属性、设置属性和调用方法。例如，以下代码包含 <FORM> 控件，可用其对标签控件的两个属性进行操作：
<FORM NAME="LabelControls">
<INPUT TYPE="TEXT" NAME="txtNewText" SIZE=25>
<INPUT TYPE="BUTTON" NAME="cmdChangeIt" VALUE="更改文本">
<INPUT TYPE="BUTTON" NAME="cmdRotate" VALUE="旋转标签">
</FORM>
通过定义过的窗体，cmdChangeIt 按钮的事件过程可更改标签文本：
<SCRIPT LANGUAGE="VBScript">
<!--
Sub cmdChangeIt_onClick
Dim TheForm
Set TheForm = Document.LabelControls
lblActiveLbl.Caption = TheForm.txtNewText.Value
End Sub
-->
</SCRIPT>
代码将对控件和值的引用限定在窗体中，这与简单验证示例中的代码类似。
ActiveX 库中有多个 ActiveX? 控件可用于 Internet Explorer。您可以在那里找到关于属性、方法和事件的全部信息，也可以在编程参考页面上找到关于控件类标识符 (CLSID) 的信息。另外还可以在 Internet Explorer 4.0 Author's Guide and HTML Reference 页面上找到有关 <OBJECT> 标记的详细信息。
-----------------------------------------------------------------------
注意 Internet Explorer 的早期版本要求用大括号 ({}) 将 classid 属性括起来，不符合 W3C 规格。在当前版本中使用大括号则会产生“此页使用了过期版本的 <OBJECT> 标记”信息。
-----------------------------------------------------------------------
